Sub SendNamedRangeAsPictureInBody()
    Dim OutlookApp As Object
    Dim OutlookMail As Object
    Dim WordEditor As Object
    Dim ws As Worksheet
    Dim strRange As String
    Dim rng As Range
    Dim InlineShape As Object

    ' Define your sheet and named range here
    Set ws = ThisWorkbook.Sheets("Bla Bla")
    strRange = "ToBookKeeping"
    
    ' Get the range
    Set rng = ws.Range(strRange)

    ' Copy the range as a picture
    rng.CopyPicture Appearance:=xlScreen, Format:=xlPicture

    ' Create the Outlook application and email
    Set OutlookApp = CreateObject("Outlook.Application")
    Set OutlookMail = OutlookApp.CreateItem(0)

    ' Construct the email
    With OutlookMail
        .To = "BookKeepersMailAddress"
        .Subject = "Hjemmeladning for den angivne periode !"
        

        ' Get the Word editor for the email and paste the image
        Set WordEditor = OutlookMail.GetInspector.WordEditor
        WordEditor.Content.Paste
        
        ' Access the last pasted inline shape (the picture) and resize it
        Set InlineShape = WordEditor.InlineShapes(WordEditor.InlineShapes.Count)
        InlineShape.LockAspectRatio = msoFalse
        InlineShape.Width = InlineShape.Width * 2 ' Double the width
        InlineShape.Height = InlineShape.Height * 2 ' Double the height
            
        WordEditor.Content.InsertAfter vbCrLf & vbCrLf '& vbCrLf
    
        ' Add additional text or formatting here if needed
        WordEditor.Content.InsertAfter "Fortsat god dag !" & vbCrLf & "TEAM SUPPORT"
    
        
        .Display    ' Display the email before sending
        '.Send       '  At sende giver FEJL !!!!!!!!!!!!!!!

    End With

    ' Clean up
    Set ws = Nothing
    Set rng = Nothing
    Set OutlookMail = Nothing
    Set OutlookApp = Nothing
    Set WordEditor = Nothing
    Set InlineShape = Nothing
   
End Sub