Microsoft Office Forums - View Single Post

Charles Kenyon · 02-07-2023, 08:34 PM

Quote:

Originally Posted by spillerbd

Y***
There is a Macro at StackOverflow that can list most the styles in the Current Style Set and the parameters. The macro as published, excludes List and Table styles.

That macro is nice, but it does not give you the descriptions of styles in a [Quick] Style Set. It gives all paragraph and character styles in a document. That is far more than are in the Quick Style Set. Only the styles set to display in the Quick Styles Gallery on the Home tab are part of a Quick Style Set. I use the braces usually when talking about these to emphasize that it is about a small set of the styles in a Word document.

Here is a modified version of Jessica Weissman's macro that reports only styles that are in or can be in a Quick Style Set. That is, those that are Quick Styles.

Code:

Sub describeAllQuickStyles()
    '  by Jessica Weissman 2012-12-05
    '  https://stackoverflow.com/questions/13706753/how-can-i-export-style-names-and-definitions-from-ms-word-2010-quickstyle-set-or
    '  modified for Quick Styles by Charles Kenyon 2023-02-07
    '  https://www.msofficeforums.com/word/50385-how-create-multiple-word-style-galleries.html#post173323
    '
    Dim docActive As Document
    Dim docNew As Document
    Dim styleLoop As Style
    '
    Set docActive = ActiveDocument
    Set docNew = Documents.Add
    For Each styleLoop In docActive.Styles
        If styleLoop.Type < 3 Then
            If styleLoop.QuickStyle = True Then     'ckk
                ' show only character and paragraph styles, not list or table styles
                With docNew.range
                    .InsertAfter Text:=styleLoop.NameLocal & Chr(9) _
                                       & styleLoop.Description
                    .InsertParagraphAfter
                    .InsertParagraphAfter
                End With
            End If              'ckk
        End If
    Next styleLoop
    Set docNew = Nothing        'ckk
    Set docActive = Nothing     'ckk
    Set styleLoop = Nothing     'ckk
End Sub

Yes, Themes are an important component. Changing the theme can make a big difference in how the Quick Style Sets act.

Here is my article on Quick Style Sets and Word Themes in Microsoft Word on the Microsoft website.