Sub ResetCCs()
    Dim aCC As ContentControl, iType As Integer
    Dim bbCat As String, bbType As Long
    For Each aCC In ActiveDocument.ContentControls
        With aCC
            Select Case .Type
                Case wdContentControlText, wdContentControlRichText, wdContentControlDate
                    .Range.Text = ""
                Case wdContentControlComboBox, wdContentControlDropdownList
                    .DropdownListEntries(1).Select
                Case wdContentControlCheckBox
                    .Checked = False
                Case wdContentControlBuildingBlockGallery
                    iType = .Type
                    bbType = .BuildingBlockType
                    bbCat = .BuildingBlockCategory
                    .Type = wdContentControlRichText
                    .Range.Text = ""
                    Do While .Range.Tables.Count > 0
                        .Range.Tables(1).Delete
                    Loop
                    .Type = iType
                    .BuildingBlockType = bbType
                    .BuildingBlockCategory = bbCat
            End Select
        End With
    Next aCC
End Sub