Microsoft Office Forums - View Single Post - How to insert colon at the start of every indentation

gmayor · 04-13-2019, 09:10 PM

Based on insufficient information, the following will do what you ask. You will need to list the names used in the string strNames each separated by |. The code should only add the colons where they are not present (based on your message text). http://www.gmayor.com/installing_macro.htm

Code:

Sub AddColons()
Dim VName As Variant
Dim oRng As Range
Dim oRng2 As Range
Dim i As Long
Const strNames As String = "JOHN|JACK"
    VName = Split(strNames, "|")
    For i = 0 To UBound(VName)
        Set oRng = ActiveDocument.Range
        With oRng.Find
            Do While .Execute(FindText:=VName(i), MatchWildcards:=True)
                If oRng.Start = oRng.Paragraphs(1).Range.Start Then
                    Set oRng2 = oRng.Duplicate
                    oRng2.End = oRng2.End + 2
                    If Not oRng2.Characters.Last = ":" Then
                        oRng.InsertAfter " :"
                    End If
                    oRng.Collapse 0
                 End If
            Loop
        End With
    Next i
End Sub