Microsoft Office Forums - View Single Post - [Solved] Creating a word file and then making a pdf from excel

gmayor · 04-30-2017, 08:27 PM

It looks like you are using late binding to Word in which case you need to use the numeric equivalents of all the Word specific commands e.g.

Code:

Private Sub CommandButton1_Click()
Dim MSWord As Object
Dim Datei As String
Dim pdfName As String
    Set MSWord = CreateObject("Word.Application")
    MSWord.Visible = True

    Datei = "D:\WordTest.doc"
    pdfName = "D:\WordTest.pdf"

    MSWord.Documents.Add
    With MSWord.Selection
        .Font.Name = "Helvetica"
        .Font.Size = 20
        .Font.Color = 255
        .Font.Bold = True
        .Font.Italic = True
        .TypeText Text:="Text"
        .TypeParagraph
    End With

    MSWord.ActiveDocument.SaveAs Datei

    MSWord.ActiveDocument.ExportAsFixedFormat _
            OutputFileName:=pdfName, _
            ExportFormat:=17, _
            OpenAfterExport:=False, _
            OptimizeFor:=0, _
            Range:=0, _
            Item:=0, _
            IncludeDocProps:=False, _
            KeepIRM:=True, _
            CreateBookmarks:=0, _
            DocStructureTags:=True, _
            BitmapMissingFonts:=True, _
            UseISO19005_1:=False

    MSWord.ActiveDocument.Close
    MSWord.Quit
    Set MSWord = Nothing

End Sub