Microsoft Office Forums - View Single Post - [Solved] Printing multiple copies of docm from Word to PDF saving file with sequential name- 001, 002 etc.

macropod · 04-11-2017, 06:30 PM

Quote:

Originally Posted by SSCMapletart

I am wanting to reduce steps...
Is there a way I can print multiple copies of a document from Word 2010 to Adobe PDF with the print automatically programmed to save file with a sequential number after the name - (e.g. DocName-001, -002, -003 etc.)

Why do you want to 'print' the documents to PDF rather than simply using Word's built-in SaveAs PDF option?

If all you need do is print the documents on paper with sequential numbering, there is no need to save them. See, for example:
https://www.msofficeforums.com/word-...numbering.html
https://www.msofficeforums.com/word-...html#post34477

If you really do need to generate PDFs, you could use the document setup described in the first link above, but with the following macro:

Code:

Sub MultiFileSave()
Dim lStart As Long, lEnd As Long, i As Long
On Error GoTo ErrHandler
With ActiveDocument
  lStart = CInt(InputBox("What is the first # to create?", _
    "Numbered Document Copier", .CustomDocumentProperties("Counter").Value + 1))
  lEnd = CInt(InputBox("What is the last # to create?", _
    "Numbered Document Copier", lStart))
  If lStart = 0 Or lStart > lEnd Then GoTo ErrHandler
  For i = lStart To lEnd
    .CustomDocumentProperties("Counter").Value = i
    .Fields.Update
    .SaveAs2 Split(.FullName, ".doc")(0) & "-" & Format(i, "000") & ".pdf", _
      Fileformat:=wdFormatPDF, AddToRecentFiles:=False
  Next
End With
ErrHandler:
End Sub

The output will be saved in the same folder and with the same name as the document you're using, except they'll be PDFs numbered as per your specification.