Microsoft Office Forums - View Single Post - [Solved] Not able to open Docx file in word 2013

macropod · 12-27-2016, 01:11 AM

That suggests the document has one or more corrupt tables. Corrupt tables can often be 'repaired' by:
• converting the tables to text and back again;
• cutting & pasting them to another document that you save the document in RTF format, which you then close then re-open before copying them back to the source document; or
• saving the document in RTF format, closing the document then re-opening it and re-saving in the doc(x) format – or see the macro below:

Code:

Sub TableRepair()
'Macro to repair damaged tables by saving each table in an RTF-format file, then
' reinserting the table from the RTF-format file into the source document.
Application.ScreenUpdating = False
Dim Rng As Range, i As Long, RTFDoc As Document, strPath As String
With ActiveDocument
  strPath = .Path & "\"
  For i = .Tables.Count To 1 Step -1
    Set Rng = .Tables(i).Range
    Set RTFDoc = Documents.Add(Visible:=False)
    With RTFDoc
      .Range.FormattedText = Rng.FormattedText
      .SaveAs2 FileName:="strPath & RTFDoc.RTF", Fileformat:=wdFormatRTF, AddToRecentFiles:=False
      .Close
    End With
    Set RTFDoc = Documents.Open(FileName:="strPath & RTFDoc.RTF", AddToRecentFiles:=False, Visible:=False)
    Rng.Tables(1).Delete
    With RTFDoc
      Rng.FormattedText = .Tables(1).Range.FormattedText
      .Close
    End With
    Kill "strPath & RTFDoc.RTF"
  Next
End With
Set Rng = Nothing: Set RTFDoc = Nothing
Application.ScreenUpdating = True
End Sub

Since Word 2013 won't open the files, repairing the table(s) manually or by running the macro should be done in Word 2007.

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm