Option Explicit
Const strWorkbook As String = "C:\Path\Forums\buttons.xlsx" 'The workbook path
Const strSheet As String = "Sheet1"        'The name of the worksheet

Sub Example()
'Graham Mayor - www.gmayor.com
Dim oFrm As New UserForm1
Dim Arr() As Variant
Dim oCtrl As Control
Dim i As Long
    Arr = xlFillArray(strWorkbook, strSheet)
    With oFrm
        For i = 0 To UBound(Arr, 2)
            For Each oCtrl In .Controls
                If oCtrl.Name = Arr(0, i) Then
                    oCtrl.Caption = Arr(1, i)
                    Exit For
                End If
            Next oCtrl
        Next i
        .Show
    End With
lbl_Exit:
    Set oCtrl = Nothing
    Exit Sub
End Sub


Private Function xlFillArray(strWorkbook As String, _
                             strWorksheetName As String) As Variant
'Graham Mayor - www.gmayor.com
Dim RS As Object
Dim CN As Object
Dim iRows As Long

    strWorksheetName = strWorksheetName & "$]"
    Set CN = CreateObject("ADODB.Connection")
    CN.Open ConnectionString:="Provider=Microsoft.ACE.OLEDB.12.0;" & _
                              "Data Source=" & strWorkbook & ";" & _
                              "Extended Properties=""Excel 12.0 Xml;HDR=YES"";"

    Set RS = CreateObject("ADODB.Recordset")
    RS.Open "SELECT * FROM [" & strWorksheetName, CN, 2, 1

    With RS
        .MoveLast
        iRows = .RecordCount
        .MoveFirst
    End With
    xlFillArray = RS.GetRows(iRows)
    If RS.State = 1 Then RS.Close
    Set RS = Nothing
    If CN.State = 1 Then CN.Close
    Set CN = Nothing
lbl_Exit:
    Exit Function
End Function