zoom

grmaraite · #1 12-02-2016, 01:40 AM

Hello everyone,

I hope that my English is understandable, sorry for my mistakes.

I am visually impaired and I therefore use a magnifier program called "Zoomtext". My problem related to Word is that Zoomtext uses the same hotkey to increase/decrease the zoom: Ctrl + the small wheel of the mouse. As a consequence, each time I want to increase/decrease the zoom of Zoomtext (and this happens really often!) and Word is opened, only the zoom of Word is changed. As I work a lot with Word these days, this is really annoying. I would like to stay at 100% of zoom in Word the whole time.

Now my question: Is it possible to fix the zoom of Word once for all or at least to remove the hotkey Ctrl+mouse for the zoom of Word?

Thanks in advance!

macropod · #2 12-02-2016, 04:49 PM

You could change Word's own document zooming to enlarge what you see on screen. For example, if you add the following two macros to Word's Normal template, most documents that you create or open will automatically zoom to fit the page width to the screen width (up to a max 150% - which you can change). The macro also sets the view to the Print Layout view and forces Word to display the rulers.

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
For Mac macro installation & usage instructions, see: http://word.mvps.org/Mac/InstallMacro.html

Code:

Private Sub Document_New()
Call Document_Open
End Sub

Private Sub Document_Open()
'Preferred zoom %
Const lZoom As Long = 150
With ActiveWindow
  'Ignore any errors
  On Error Resume Next
  'Reduce flickering while changing settings
  .Visible = False
  'Switch to a single view pane
  .View.SplitSpecial = wdPaneNone
  'Switch to Normal mode
  .View.Type = wdNormalView
  With .ActivePane.View.Zoom
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Round down to nearest 10%
    .Percentage = Int(.Percentage / 10) * 10
    'Test zoom % and reduce to lZoom% max
    If .Percentage > lZoom Then .Percentage = lZoom
  End With
  'Switch to Print Preview mode
  .View.Type = wdPrintView
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Round down to nearest 10%
    .Percentage = Int(.Percentage / 10) * 10
    'Test zoom % and reduce to lZoom% max
    If .Percentage > lZoom Then .Percentage = lZoom
  End With
  'Display the Rulers
  .ActivePane.DisplayRulers = True
  'Restore the window now that we're finished
  .Visible = True
End With
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
OneNote Zoom in	Techno_y0	OneNote	1	04-27-2015 02:14 AM
Zoom-in and -out	mpv55	PowerPoint	0	10-28-2013 08:01 AM
Can't zoom in - PPT 2013?	TheDave777	PowerPoint	1	04-19-2013 08:54 AM
Zoom in transitions	pdj	PowerPoint	1	11-01-2012 11:14 AM
Zoom In and Out	DAC8190	PowerPoint	1	03-16-2011 08:50 AM