Select pagagraphs between two words and run macro

jeffreybrown · #1 09-08-2018, 03:32 PM

This macro is working fine to select all of the paragraphs between two specific words, but it's also selecting the end of the first word thereby changing the style on the first word. I would only like the paragraphs in-between the two words selected.

Is there an adjustment that can be made with this macro?

Code:

Sub RevisedFindIt()
    Dim rng1 As Range
    Dim rng2 As Range
    Dim strTheText As String
    Set rng1 = ActiveDocument.Range
    If rng1.Find.Execute(FindText:="References") Then
        Set rng2 = ActiveDocument.Range(rng1.End, ActiveDocument.Range.End)
        If rng2.Find.Execute(FindText:="Abbreviations and Acronyms") Then
            ActiveDocument.Range(rng1.End, rng2.Start).Select
            Call Format_AFI_References
        End If
    End If
End Sub

References

Paragraph 1
Paragraph 2
Paragraph 3
etc.,

Abbreviations and Acronyms

macropod · #2 09-08-2018, 04:02 PM

Try something along the lines of:

Code:

Sub Find_AFI_Ref()
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "References*Abbreviations and Acronyms"
    .Replacement.Text = ""
    .Forward = True
    .Format = False
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  If .Find.Found = True Then
    .Start = .Paragraphs.First.Range.End
    .End = .Paragraphs.Last.Range.Start
    Call Format_AFI_References(.Duplicate)
  End If
End Sub

Note how the code passes the relevant range to Format_AFI_References, which you would now code as:

Code:

Sub Format_AFI_References(Rng as Range)
With Rng
…
End With
End Sub

jeffreybrown · #3 09-08-2018, 05:25 PM

Thanks Paul, this works great.

I see how the .Duplicate is what passes the Rng, but I can't figure out or actually understand how the asterisk works in the .Text statement?

macropod · #4 09-08-2018, 08:27 PM

Quote:

Originally Posted by jeffreybrown

I can't figure out or actually understand how the asterisk works in the .Text statement?

You'll note that the code employs:
.MatchWildcards = True
the asterisk, when used with that, tells Word to find any content beginning with 'References' and ending with 'Abbreviations and Acronyms'. Being a wildcard Find, it's also case-sensitive, which means it won't give false matches with ranges that include either of those in any other case format.

jeffreybrown · #5 09-09-2018, 05:31 AM

Thanks Paul for the additional information. This helps tremendously.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Attempting to find text, select words before it, and format the entire selection	KeviM	Word VBA	1	04-07-2017 05:36 PM
How to select all incorrect words in Word at once	Slavagl	Word	2	03-23-2017 11:15 PM
How to select different words at once	FTL	Word	5	03-08-2016 06:10 PM
Macro for select words?	Megan Sprack	Word	1	08-23-2012 03:03 PM
Macro to select tables	ubns	Word VBA	5	04-15-2012 11:44 PM