Macro to search for a particular word, copy the entire paragraph to a new document

Productivity · #1 08-16-2017, 01:34 AM

Dear colleagues
I need help to create a macro.

I have a document about 100 pages . The document is already arranged in paragraphs.

I need to go into that existing document on the screen and then use a macro that performs the following functions.

Search for the particular word which I would input into the macro . Say I need to search for President.

Wherever that word President appears in any paragraph the macro must extract the entire text in that paragraph
in which that word President appears.

The macro must place all those extracted paragraphs into one which contain the word President

into a new document or the bottom or top of the existing document.

Some help will be much appreciated

macropod · #2 08-16-2017, 02:10 AM

Try:

Code:

Sub Demo()
Application.ScreenUpdating = False
Dim strFnd As String, DocSrc As Document, DocTgt As Document
strFnd = InputBox("What is the Text to Find")
If Trim(strFnd) = "" Then Exit Sub
Set DocSrc = ActiveDocument: Set DocTgt = Documents.Add
With DocSrc.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = strFnd
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    DocTgt.Characters.Last.FormattedText = .Paragraphs(1).Range.FormattedText
    .End = .Paragraphs(1).Range.End
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

EskoBrummel · #3 10-25-2019, 06:40 AM

Greetings,
This is a very useful macro, though is it possible to add the following features?
- Add the page number and document title where the paragraph is located above each paragraph;
- Enable search and extraction for multiple terms;
- Performing this macro over multiple documents.

Any of these features would be greatly appreciated!

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Create Word macro to delete text throughout the entire document	JTell	Word VBA	8	07-06-2022 12:19 PM
Copy the entire paragraph in wildcards	asderam	Word VBA	0	01-28-2021 05:54 PM
Delete entire paragraph after key word	jeffreybrown	Word	2	07-27-2018 02:29 PM
How to select and copy to clipboard an entire document except for a paragraph and keep formatting	TD_123	Word VBA	7	06-16-2015 03:30 PM
align just ONE paragraph, not the entire document	vcolemonts	Word	1	02-18-2014 09:57 AM