I am new in PowerPoint (2007). So i am somewhat suprised that i cant make a macro recording In PP.
So how do i make a printing command in VB in PP.
Every time i go to the macro recorder PP goes to the VB script screen.



I have tried to make Print commands but it doesn't work.

Can somebody help in the right direction?

the macro recorder hasn't worked well for quite a while as PPT got progressively more complex and was eventually scrapped.

You need to say WHAT you want to print but here are some ideas

PRINT IT ALL AS SLIDE IMAGES

Sub PRNT_ALL()
With ActivePresentation.PrintOptions
.OutputType = ppPrintOutputSlides
.RangeType = ppPrintAll
End With
ActivePresentation.PrintOut
End Sub

PRINT SOME SLIDES (2-3)

Sub PRNT_2and3()
With ActivePresentation.PrintOptions
.OutputType = ppPrintOutputSlides
.RangeType = ppPrintSlideRange
.Ranges.ClearAll ' always clear old settings
.Ranges.Add Start:=2, End:=3
End With
ActivePresentation.PrintOut
End Sub

PRINT THE CURRENT SLIDE IN SHOW MODE

Sub PRNT_CURRENT_SHOWMODE()
Dim curr As Long
curr = SlideShowWindows(1).View.CurrentShowPosition
' This is only for printing in show
' it will error in edit mode
' Never use ppPrintCurrent in show mode
' it refers to the current slide in edit mode which may be different
With ActivePresentation.PrintOptions
.OutputType = ppPrintOutputSlides
.RangeType = ppPrintSlideRange
.Ranges.ClearAll ' alway clear old settings
.Ranges.Add Start:=curr, End:=curr
End With
ActivePresentation.PrintOut
End Sub

__________________
Microsoft PowerPoint MVP 2007-2023
Free Advanced PowerPoint Tips and Tutorials

Thank you verry much!
ik can work with this!
I did not realize that they scrapped the macro recorder.