Hello. I'm relatively new to vba and need some help. I have an excel user form that has a combobox and a number of text boxes, the combobox contains a list of course names. When the user clicks a course name in the combobox the text boxes are then populated by information that is relevant to this course such as cost of course, length of course and the tutor's name and contact number. What I want to do is put a command button on the form so that when the user choses a course in the combobox and all the relevant information is added to the text boxes the user then clicks the command button and this information is copied into a word template. I know how to add the command button and I am quiet happy creating the Word Template I just don't know how to code the command button to copy the data to the word template (I have created form fields in my word template). I am using office 2013 for Windows



Any help would be greatly appreciated.

Hi there,

Let me know if this code stub helps you work this one out?

Kind regards

Private Sub DataToWordTemplate()

Dim oWordApp As Word.Application
Dim oWordDoc As Word.Document

Dim lComboBoxIndex As Long

On Error Resume Next
Set oWordApp = GetObject(, "Word.Application")
If Not Err.Number = 0 Then
Err.Clear
Set oWordApp = New Word.Application
End If

On Error GoTo ErrorHandler
oWordApp.Visible = True

' Provide the path to your template
Set oWordDoc = oWordApp.Documents.Add("C:\WordTemplate.dotx", False, wdNewBlankDocument, True)

' Code stub for one form field
lComboBoxIndex = Me.ComboBox1.ListIndex

If lComboBoxIndex >= 0 Then

' To set the text in a FormField
If oWordDoc.FormFields.Count >= 1 Then
' Where Text1 is the Name you gave to the Form Field
oWordDoc.FormFields.Item("Text1").Result = Me.ComboBox1.List(lComboBoxIndex)
End If

End If

CleanUp:
Set oWordDoc = Nothing
Set oWordApp = Nothing

Exit Sub
ErrorHandler:
MsgBox "An error has occurred." & vbCr & vbCr & _
Err.Number & " " & Err.Description
Err.Clear
GoTo CleanUp
End Sub